67849a3279
The meson build system allows projects to "vendor" dtc easily, thanks to subproject(). QEMU has recently switched to meson, and adding meson support to dtc will help to handle the QEMU submodule. meson rules are arguably simpler to write and maintain than the hand-crafted/custom Makefile. meson support various backends, and default build options (including coverage, sanitizer, debug/release etc, see: https://mesonbuild.com/Builtin-options.html) Compare to the Makefiles, the same build targets should be built and installed and the same tests should be run ("meson test" can be provided extra test arguments for running the equivalent of checkm/checkv). There is no support EXTRAVERSION/LOCAL_VERSION/CONFIG_LOCALVERSION, instead the version is simply set with project(), and vcs_tag() is used for git/dirty version reporting (This is most common and is hopefully enough. If necessary, configure-time options could be added for extra versioning.). libfdt shared library is build following regular naming conventions: instead of libfdt.so.1 -> libfdt-1.6.0.so (with current build-sys), libfdt.so.1 -> libfdt.so.1.6.0. I am not sure why the current build system use an uncommon naming pattern. I also included a libfdt.pc pkg-config file, as convenience. Both Linux native build and mingw cross-build pass. CI pass. Tests are only run on native build. The current Makefiles are left in-tree, and make/check still work. Eventually, the Makefiles could be marked as deprecated, to start a transition period and avoid having to maintain 2 build systems in the near future. (run_tests.sh could eventually be replaced by the meson test runner, which would have several advantages in term of flexibility/features, but this is left for another day) Signed-off-by: Marc-André Lureau <marcandre.lureau@redhat.com> Message-Id: <20201012073405.1682782-3-marcandre.lureau@redhat.com> Signed-off-by: David Gibson <david@gibson.dropbear.id.au>
50 lines
928 B
Meson
50 lines
928 B
Meson
version_script = '-Wl,--version-script=@0@'.format(meson.current_source_dir() / 'version.lds')
|
|
if not cc.has_link_argument(version_script)
|
|
version_script = []
|
|
endif
|
|
|
|
sources = files(
|
|
'fdt.c',
|
|
'fdt_addresses.c',
|
|
'fdt_check.c',
|
|
'fdt_empty_tree.c',
|
|
'fdt_overlay.c',
|
|
'fdt_ro.c',
|
|
'fdt_rw.c',
|
|
'fdt_strerror.c',
|
|
'fdt_sw.c',
|
|
'fdt_wip.c',
|
|
)
|
|
|
|
libfdt = library(
|
|
'fdt', sources,
|
|
version: '1.6.0',
|
|
link_args: ['-Wl,--no-undefined', version_script],
|
|
link_depends: 'version.lds',
|
|
install: true,
|
|
)
|
|
|
|
libfdt_inc = include_directories('.')
|
|
|
|
libfdt_dep = declare_dependency(
|
|
include_directories: libfdt_inc,
|
|
link_with: libfdt,
|
|
)
|
|
|
|
install_headers(
|
|
files(
|
|
'fdt.h',
|
|
'libfdt.h',
|
|
'libfdt_env.h',
|
|
)
|
|
)
|
|
|
|
pkgconfig = import('pkgconfig')
|
|
|
|
pkgconfig.generate(
|
|
libraries: libfdt,
|
|
version: meson.project_version(),
|
|
filebase: 'libfdt',
|
|
name: 'libfdt',
|
|
description: 'Flat Device Tree manipulation',
|
|
)
|