cc39f63773
Divide policy into public and private components. This is the first step in splitting the policy creation for platform and non-platform policies. The policy in the public directory will be exported for use in non-platform policy creation. Backwards compatibility with it will be achieved by converting the exported policy into attribute-based policy when included as part of the non-platform policy and a mapping file will be maintained to be included with the platform policy that maps exported attributes of previous versions to the current platform version. Eventually we would like to create a clear interface between the platform and non-platform device components so that the exported policy, and the need for attributes is minimal. For now, almost all types and avrules are left in public. Test: Tested by building policy and running on device. Change-Id: Idef796c9ec169259787c3f9d8f423edf4ce27f8c
54 lines
1.2 KiB
Text
54 lines
1.2 KiB
Text
########################################
|
|
#
|
|
# gen_cats(N)
|
|
#
|
|
# declares categores c0 to c(N-1)
|
|
#
|
|
define(`decl_cats',`dnl
|
|
category c$1;
|
|
ifelse(`$1',`$2',,`decl_cats(incr($1),$2)')dnl
|
|
')
|
|
|
|
define(`gen_cats',`decl_cats(0,decr($1))')
|
|
|
|
########################################
|
|
#
|
|
# gen_sens(N)
|
|
#
|
|
# declares sensitivites s0 to s(N-1) with dominance
|
|
# in increasing numeric order with s0 lowest, s(N-1) highest
|
|
#
|
|
define(`decl_sens',`dnl
|
|
sensitivity s$1;
|
|
ifelse(`$1',`$2',,`decl_sens(incr($1),$2)')dnl
|
|
')
|
|
|
|
define(`gen_dominance',`s$1 ifelse(`$1',`$2',,`gen_dominance(incr($1),$2)')')
|
|
|
|
define(`gen_sens',`
|
|
# Each sensitivity has a name and zero or more aliases.
|
|
decl_sens(0,decr($1))
|
|
|
|
# Define the ordering of the sensitivity levels (least to greatest)
|
|
dominance { gen_dominance(0,decr($1)) }
|
|
')
|
|
|
|
########################################
|
|
#
|
|
# gen_levels(N,M)
|
|
#
|
|
# levels from s0 to (N-1) with categories c0 to (M-1)
|
|
#
|
|
define(`decl_levels',`dnl
|
|
level s$1:c0.c$3;
|
|
ifelse(`$1',`$2',,`decl_levels(incr($1),$2,$3)')dnl
|
|
')
|
|
|
|
define(`gen_levels',`decl_levels(0,decr($1),decr($2))')
|
|
|
|
########################################
|
|
#
|
|
# Basic level names for system low and high
|
|
#
|
|
define(`mls_systemlow',`s0')
|
|
define(`mls_systemhigh',`s`'decr(mls_num_sens):c0.c`'decr(mls_num_cats)')
|