plugins {
    id 'jacoco'
    id 'org.jetbrains.kotlin.jvm' version '1.3.61' apply false
    id "org.jlleitschuh.gradle.ktlint" version "9.1.1"
}

subprojects {
    version = "0.13.0-SNAPSHOT"
    group = "io.github.wulkanowy"
}

ext {
    PUBLISH_VERSION = '0.13.0'
    SITE_URL = 'https://github.com/wulkanowy/sdk'
    GIT_URL = 'https://github.com/wulkanowy/sdk.git'

    jspoon = "1.3.2"
    okhttp3 = "3.12.6"
    retrofit = "2.6.3"
    threetenbp = "1.4.0"
    slf4j = "1.7.29"
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'kotlin'
    apply plugin: "org.jlleitschuh.gradle.ktlint"

    ktlint {
        additionalEditorconfigFile = file(".editorconfig")
        disabledRules = [
            "no-wildcard-imports",
            "import-ordering",
            "max-line-length"
        ]
    }

    sourceCompatibility = 1.8

    compileKotlin {
        kotlinOptions {
            jvmTarget = "1.6"
            javaParameters = true
        }
    }

    repositories {
        mavenCentral()
        jcenter()
        maven { url "https://jitpack.io" }
    }

    dependencies {
        implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"

        implementation "io.reactivex.rxjava2:rxjava:2.2.15"
        implementation "com.squareup.okhttp3:logging-interceptor:$okhttp3"

        compileOnly "org.threeten:threetenbp:$threetenbp:no-tzdb"
        testImplementation "org.threeten:threetenbp:$threetenbp"

        testImplementation "com.squareup.okhttp3:mockwebserver:$okhttp3"
        testImplementation "junit:junit:4.12"
    }

    jacocoTestReport {
        reports {
            xml.enabled true
        }
    }

    test {
        testLogging.showStandardStreams = false
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    artifacts {
        archives sourcesJar
        archives javadocJar
    }
}